Исполнительные устройства

Arduino умеет не только «чувствовать» (кнопки, датчики), но и «действовать». Детали, которые что-то делают — светят, звучат, двигаются, — называют исполнительными устройствами. Сегодня их два: светодиод и пищалка.

Оба подключаются к цифровым пинам и управляются одинаково: пин делаем выходом (OUTPUT), а потом подаём на него 5 вольт (HIGH) или 0 вольт (LOW).

pinMode(7, OUTPUT);      // пин 7 — выход
digitalWrite(7, HIGH);   // подать 5 В — светодиод горит
digitalWrite(7, LOW);    // подать 0 В — светодиод погас

Светодиод: три правила подключения

1. Полярность. Длинная ножка — анод (+), к ней приходит сигнал от пина. Короткая — катод (−), она идёт к земле GND. Со стороны катода на ободке корпуса есть срез.
2. Резистор обязателен и стоит со стороны плюса: пин → резистор 220 Ом → длинная ножка. Без резистора потечёт слишком большой ток, и сгорит светодиод или пин Arduino.
3. Короткая ножка — в минус через провод. Короткую ножку вставляем в свой столбец, а от него чёрный провод идёт в синюю шину «−». Шина соединена проводом с GND Arduino.

Почему именно 220 Ом? Посчитаем ток по закону Ома. На светодиоде «теряется» около 2 В, на резистор остаётся 5 − 2 = 3 В:

Пин Arduino спокойно выдаёт до 20 мА, светодиоду тоже нормально — светит ярко и не перегревается. Если резистор поставить со стороны минуса, ток будет тот же: в цепи из последовательно соединённых деталей он одинаковый везде. Мы ставим его со стороны плюса.

Пищалка: откуда берётся звук

Внутри пищалки — тонкая пластинка из пьезокерамики. Когда на неё подают напряжение, она чуть-чуть выгибается. Если очень быстро включать и выключать напряжение, пластинка дрожит и толкает воздух — получается звук.

Сколько раз в секунду пластинка дрожит, такая у звука частота. Её измеряют в герцах: 1000 Гц — это 1000 колебаний в секунду. Чем выше частота, тем выше и тоньше звук. Человек слышит примерно от 20 до 20 000 Гц, а пищалка громче всего звучит около 2000–4000 Гц.

Для сирены нужна пассивная пищалка: только у неё можно менять частоту. У пищалки тоже есть полярность: вывод «+» подключаем к пину, второй — к GND.

Команды tone() и noTone()

tone(8, 1000);        // пищать на пине 8 частотой 1000 Гц,
                      // пока не выключим
tone(8, 1000, 200);   // пищать 200 мс — звук выключится сам
noTone(8);            // выключить звук на пине 8

• tone() не останавливает программу. Звук идёт «в фоне», а следующие команды выполняются сразу. Поэтому, чтобы дослушать звук, после tone() часто ставят delay().
• Звук продолжается, пока его не выключат noTone() или не поменяют следующим tone() с другой частотой.
• Одновременно может звучать только один tone().

Сирена: свет и звук по фазам

Сирена — это повторяющиеся фазы. В каждой фазе одновременно включаются свой цвет и свой звук. Секрет синхронизации простой: команды для света и для звука стоят рядом, без delay() между ними, а пауза — одна на всю фазу.

// Фаза 1: красный + высокий тон
digitalWrite(RED_LED, HIGH);
digitalWrite(BLUE_LED, LOW);
tone(BUZZER, 1000);
delay(400);
// Фаза 2: синий + низкий тон
digitalWrite(RED_LED, LOW);
digitalWrite(BLUE_LED, HIGH);
tone(BUZZER, 750);
delay(400);

Бывает и сирена-«вой»: частота плавно растёт и падает. Её делают циклом for, который много раз немного меняет частоту:

for (int freq = 600; freq <= 1500; freq = freq + 10) {
  tone(BUZZER, freq);   // каждый шаг — чуть выше
  delay(5);
}

Почему delay() мешает

delay(400) — это «сон»: 400 мс Arduino ничего не делает и ничего не замечает. Пока работает только сирена, это не страшно. Но если добавить кнопку, Arduino будет проверять её только между «снами», и короткое нажатие потеряется.

Представьте охранника, который каждые полсекунды закрывает глаза на 0,4 секунды. Вора он заметит не всегда.

Попробуйте в примере справа: нажимайте кнопку в разные моменты. Сверху Arduino «спит» в delay(), снизу проверяет кнопку постоянно.

millis() — часы внутри Arduino

millis() сообщает, сколько миллисекунд прошло с момента включения Arduino. Это секундомер, который никогда не останавливается. Вместо того чтобы «спать», программа постоянно смотрит на часы и спрашивает: «Не пора ли?»

unsigned long lastSwitch = 0;   // когда последний раз переключали

void loop() {
  if (millis() - lastSwitch >= 400) {   // прошло 400 мс?
    lastSwitch = millis();              // запомнили время
    // ... переключаем фазу сирены
  }
  // здесь же успеваем проверять кнопку
}

Так loop() выполняется тысячи раз в секунду, и в каждом проходе Arduino успевает и проверить кнопку, и, если пора, переключить сирену. Получается параллельная работа.

Кнопка и INPUT_PULLUP

Кнопка — устройство ввода. Arduino читает её командой digitalRead(), которая возвращает HIGH или LOW.

Если пин ни к чему не подключён, он «висит в воздухе» и ловит помехи: digitalRead() выдаёт то HIGH, то LOW случайно. Чтобы этого не было, пин через резистор «подтягивают» к +5 В. У Arduino такой резистор есть внутри — его включает одна команда:

pinMode(BUTTON, INPUT_PULLUP);   // вход с подтяжкой к +5 В
int b = digitalRead(BUTTON);     // отпущена → HIGH, нажата → LOW

Кнопка подключается одной ножкой к пину 2, другой — к GND. Нажали — пин соединился с землёй, и Arduino прочитала LOW. Да, наоборот: нажата = LOW.

Дребезг контактов и кнопка-выключатель

Металлические контакты кнопки при нажатии несколько раз «подпрыгивают», и за 1–5 мс сигнал успевает много раз смениться. Arduino очень быстрая и может посчитать одно нажатие за несколько. Это называется дребезг.

Лечится просто: заметили изменение — подождали 50 мс, пока контакты успокоятся. А чтобы кнопка работала как выключатель (нажал — вкл, нажал ещё раз — выкл), ловим момент нажатия и переворачиваем переменную знаком ! («не»):

int button = digitalRead(BUTTON);
if (button != lastButton) {    // состояние изменилось
  delay(50);                   // ждём конца дребезга
  if (button == LOW) {         // это было нажатие
    guardOn = !guardOn;        // true ↔ false
  }
  lastButton = button;         // запоминаем
}

Режимы работы (состояния)

Сложное устройство удобно описывать режимами. Наша сигнализация всегда находится ровно в одном из трёх режимов и в каждом ведёт себя по-своему. Из режима в режим её переводят события: нажатие кнопки или истечение времени.

const int MODE_OFF    = 0;   // выключено
const int MODE_ARMING = 1;   // постановка: 5 секунд на выход
const int MODE_GUARD  = 2;   // охрана: сирена
int mode = MODE_OFF;         // текущий режим

if (mode == MODE_ARMING) {
  // мигаем жёлтым и смотрим, не прошло ли 5 секунд
}

Так устроены светофоры, стиральные машины, лифты и настоящие сигнализации. В программировании такую схему называют конечным автоматом.

Цифровой и аналоговый сигнал

Цифровой сигнал похож на выключатель: у него только два значения — 0 В или 5 В (LOW или HIGH). Аналоговый похож на ручку громкости: он может быть любым в диапазоне — 1,7 В, 3,24 В и так далее.

Цифровые пины D0–D13 отвечают только «да» или «нет». Чтобы измерить «сколько», у Arduino Uno есть шесть аналоговых входов: A0–A5.

Потенциометр

Потенциометр — это резистор с тремя выводами и ручкой. Внутри — подковообразная дорожка из резистивного материала (у нас 10 кОм) и подвижный контакт — движок.

• Крайние выводы подключены к концам дорожки: один — к 5V, другой — к GND.
• Средний вывод соединён с движком. Его подключаем к аналоговому входу A0.
• Крутим ручку — движок скользит по дорожке, и напряжение на среднем выводе плавно меняется от 0 до 5 В.

Покрутите ручку в примере справа мышкой или пальцем. Пример показывает сразу всё: где движок, какое напряжение, какое число получит Arduino и как это число записано в двоичном виде.

Делитель напряжения

Два резистора, соединённые последовательно между 5 В и землёй, делят напряжение. В точке между ними получается часть от 5 В — тем больше, чем больше нижний резистор:

• R1 = R2 = 5 кОм → U = 5 × 5 / 10 = 2,5 В (половина).
• R1 = 7,5 кОм, R2 = 2,5 кОм → U = 5 × 2,5 / 10 = 1,25 В (четверть).

Потенциометр — это делитель, у которого соотношение R1 и R2 меняется поворотом ручки. Их сумма всегда равна 10 кОм.

АЦП: как напряжение превращается в число

Внутри Arduino есть АЦП — аналого-цифровой преобразователь. Он делит диапазон 0–5 В на 1024 ступеньки и сообщает номер ступеньки: от 0 до 1023.

Почему 1024? Потому что АЦП 10-битный: из 10 двоичных разрядов можно составить 2¹⁰ = 1024 разных числа.

analogRead() и Монитор порта

int value = analogRead(A0);   // число от 0 до 1023

Монитор порта — окно, в которое Arduino по USB-кабелю пишет сообщения. Это главный способ узнать, что происходит внутри программы.

void setup() {
  Serial.begin(9600);       // включить связь, скорость 9600 бод
}
void loop() {
  int value = analogRead(A0);
  Serial.print("A0 = ");    // print — без перехода на новую строку
  Serial.println(value);    // println — с переходом
  delay(200);
}

• Открыть: значок лупы справа вверху Arduino IDE или Ctrl + Shift + M.
• Скорость в окне монитора должна совпадать с Serial.begin() — 9600. Иначе вместо чисел будут непонятные символы.
• Если печатать только числа (Serial.println(value)), «Плоттер по последовательному соединению» нарисует график.

map(): пересчёт из одного диапазона в другой

Число 0…1023 часто нужно превратить во что-то другое: в паузу 50…1000 мс, в угол 0…180°, в количество светодиодов. Для этого есть функция map():

int pause = map(value, 0, 1023, 50, 1000);
//              что    из диапазона  в диапазон

• map(0, 0, 1023, 50, 1000) → 50
• map(512, 0, 1023, 50, 1000) → 525
• map(1023, 0, 1023, 50, 1000) → 1000

map() работает с целыми числами и отбрасывает дробную часть. Диапазон можно и перевернуть: map(value, 0, 1023, 1000, 50) — тогда чем дальше ручка, тем меньше результат.

Пороги: шкала и авария

Чтобы светодиоды загорались по очереди, каждому назначаем порог: светодиод горит, если значение больше его порога.

if (value > 200) {
  digitalWrite(LED1, HIGH);   // выше порога — горит
} else {
  digitalWrite(LED1, LOW);    // ниже — не горит
}

Авария — это ещё один порог, близкий к максимуму: if (value > 1000). Ставить ровно 1023 не стоит: из-за шума значение может не дотягивать до максимума.